c={(1-s^2)/(1+s^2),(2s)/(1+s^2)}
dc=Simplify[D[c,s]]
rc=Simplify[Sqrt[Factor[dc.dc]],Element[s,Reals] ]

Integrate[rc, {s, 0,1}]

ParametricPlot[c, {s, 0,1}]

c/.{s->1/2}

Plot[rc, {s, 0,1}, AxesOrigin->{0,0}]

repar={s->((l+1)*t)/(l*t+1)}

repar/.{t->0}

Manipulate[Plot[(s/.repar)/.{l->L}, {t,0,1}, AspectRatio->Automatic, AxesOrigin->{0,0}],{L, -0.8, 20}]

c1=Simplify[c/.repar]

Factor[c1/.{t->1/2}]==Normalize[{1,1}]

res=Solve[{((3+2 l)/(5+6 l+2 (l^2))),((2 (1+l) (2+l))/(5+6 l+2 (l^2)))}=={(1/(Sqrt[2])),(1/(Sqrt[2]))}][[1]]

c1=Factor[c1/.res]

dc1=D[c1,t];

rc1=Simplify[Sqrt[dc1.dc1], t>0]

Plot[rc1, {t, 0,1}, AxesOrigin->{0,0}]

Factor[1+2 (-2+(Sqrt[2])) t+(10-6 (Sqrt[2])) (t^2)+4 (-3+2 (Sqrt[2])) (t^3)+(6-4 (Sqrt[2])) (t^4), Extension->Sqrt[2]]

Solve[CoefficientList[(a+b*t+cc*t^2)^2-(1+2 (-2+(Sqrt[2])) t+(10-6 (Sqrt[2])) (t^2)+4 (-3+2 (Sqrt[2])) (t^3)+(6-4 (Sqrt[2])) (t^4)),t]==0, {a,b,cc}]

card={2Cos[t]-(Cos[t]^2-Sin[t]^2),2Sin[t]-2*Sin[t]*Cos[t]}

Dcard=D[card,t]

speedCard=Sqrt[Simplify[Dcard.Dcard]]

pl1=ParametricPlot[card,{t,-Pi, Pi}, PlotStyle->Magenta];

krCard=FullSimplify[Det[{Dcard, D[Dcard,t]}]/speedCard^3]

Plot[krCard, {t, -Pi,Pi}, AxesOrigin->{0,0}]

t0=Pi/2

card0=card/.{t->t0}

krCard0=krCard/.{t->t0}

R0=1/krCard0

T0=Normalize[Dcard/.{t->t0}]
T=Simplify[Normalize[Dcard], t>0]

NN={{0,-1},{1,0}}.T

N0={{0,-1},{1,0}}.T0

S0=card0+R0*N0

pl2=Show[pl1, Graphics[{PointSize[0.02],Point[{card0,S0}]}], Graphics[{Dashed, Circle[S0, R0]}]]

osKr=S0+R0*(Cos[s-t0]*(-N0) +Sin[s-t0]*T0)

osKr/.{s->t0}

Show[pl1, Graphics[{PointSize[0.02],Point[{card0,S0}]}], ParametricPlot[osKr, {s,-Pi/2, Pi/2}], Graphics[{Dashed, Circle[S0, R0]}]]

Series[card,{t, t0, 4}]

Series[osKr,{s, t0, 4}]

a

osKrNice=osKr/.{s->Pi/2+a1*(t-Pi/2)+a2*(t-Pi/2)^2}

res=Solve[Flatten[CoefficientList[Normal[Series[(osKrNice-card),{t, t0, 2}]], t]]==0, {a1,a2}][[1]]

osKrSuperNice=osKrNice/.res

Series[card,{t, t0, 4}]

Series[osKrSuperNice,{t, t0, 4}]

normala=card+s*NN

normala0=normala/.{t->t0}

prusecik=FullSimplify[normala/.Solve[normala==(normala0/.{s->ss}), {s,ss}]][[1]]

Manipulate[Show[pl2,ParametricPlot[normala0, {s,-0.2,3}], ParametricPlot[normala/.{t->S}, {s,-0.2,3}], Graphics[{Red, PointSize[0.02],Point[prusecik/.{t->S}]}]],{{S,Pi/2},Pi/2-1, Pi/2+1}]

Limit[prusecik, t->t0]

S0