## jednoduchy graf 
## a jak jej ulozit jako obrazek .gif


set size ratio 0.5
	## pomer obrazku y/x 


pi=3.14
	## pomocna konstanta


plot [0:3*pi/2] sin(x) lc rgb "gold"
	## [a:b] ... interval pro _x_
	## lc ... linecolor


### ULOZENI obrazku do SOUBORU ....

set terminal gif
	## format vystupu
set output "prubeh_sinu.gif"
	## jmeno souboru

replot
	## ulozi se do souboru
	 

 
	## jednoduchy parametricky plot

set parametric
	## parametricky plot

set tr[0:10]
	## parametr _t_ od 0 do 10

r(t) = t/(t+1)
	## pomocna funkce

set size square
	## ctvercovy obrazek

plot  r(t)*cos(t) , r(t)*sin(t) lc rgb "blue"
	## kresli modrou spiralu...
	 

 
	## 3d obrazek (s viditelnosti)

set hidden3d
	## skryt spodek grafu

set isosamples 35
	## jemnost site

r(x,y) = sqrt(x*x + y*y)
	## pomocna funkce

splot sin(r(x,y))/ r(x,y)
	## vykresli
	 

 
	## 3d parametricky plot (zde proste koule)

set parametric
	## parametricky plot

pi = 3.14159
	## pomocna konstanta

set ur[0:2*pi]
set vr[-pi:pi]
	## rozsah parametru _u_ a _v_


set size square
set isosamples 20

splot cos(u)*cos(v), sin(u)*cos(v), sin(v)
	## kresli kouli...
	 

 
	## vykresleni urovnovych krivek ("vrstevnic") funkce
## dva zpusoby...

### vrstevnice se kresli jako 3d graf, kde

set contour
	## chci videt jen obrysy
set nosurface
	## nechci videt plochy
set view 0,0
	## pohled shora
set isosamples 40,40
	## jemnost site (default = 10, coz je malo)

set noclabel
	## vsechny krivky stejne barvy a bez popisek

set size square
	## ctvercovy obrazek



set xr[-2:2]
set yr[-2:2]
	## rozsah _x_ a _y_

set cntrparam levels discrete 0.01 , 0.2 , 2, 7, 15
	## chci vrstevnice techto hodnot

splot x*x*x*x + y*y*y*y lc rgb "blue"
	## vykresli (modre)

pause -1

### JINY ZPUSOB:

set xr[-3:1]
set yr[-2:2]

set cntrparam levels incremental -1, .25, 1
	## chci vrstevnice od -1 do 1 s krokem 0.25
	#
splot x+y*y lc rgb "brown"
	## vykresli (hnede)